' +---------------------------------------------------------------------+
    ' |                                                                     |
    ' |                       - P a g e . B a s -                           |
    ' |                                                                     |
    ' |                                                                     |
    ' |                   Public Domain -  FreeWare                         |
    ' +---------------------------------------------------------------------+
    ' +---------------------------------------------------------------------+
    ' |                      - ABOUT THE AUTHOR -                           |
    ' +---------------------------------------------------------------------+
    ' |                                                                     |
    ' | Hello. My name is Don Smith and I am a thirty-year retired teacher  |
    ' | of Math/History/Spanish residing in Orange County, California. I    |
    ' | am also a former six-year Sergeant of Marines. Who-Rah! On certain  |
    ' | forums I am known as MarineDon. My email is: smithdonb@earthlink.net|
    ' |                                                                     |
    ' +---------------------------------------------------------------------+
    ' |                 - COPYING AND DISTIBUTING -                         |
    ' +---------------------------------------------------------------------+
    ' | Since this code is public domain and freeware, anyone may freely    |
    ' | copy and distribute it. If you use the QuickBasic code in one of    |
    ' | your own programs, you do not have to cite my name as the author,   |
    ' | and you may even change its name.                                   |
    ' +---------------------------------------------------------------------+  
    ' +---------------------------------------------------------------------+
    ' | Page.Bas is an example of how to use the MesaMenu SUB to show       |
    ' | regular menu items.   Page.Bas is Public Domain, FreeWare. See      |
    ' | MM.Bas for complete details of MesaMenu                             |
    ' |                                                                     |
    ' |              Written by Don Smith on 08/01/2002.                    |
    ' |               EMail: smithdonb@earthlink.net                        |
    ' +---------------------------------------------------------------------+

    DEFINT A-Z
    '-----------------------------------------------------------------------
    DECLARE SUB BoxBoy (Title$, ULRow%, ULCol%, LRRow%, LRCol%, TitleRow%, TitleCol%, TitColrFor%, TitColrBak%, BoxColrFor%, BoxColrBak%, BoxStyle%, Shadow%, ShadowColr%, ClearColr%)
    DECLARE SUB MesaMenu (M$(), Start%, Count%, RegColrFG%, RegColrBG%, HiLiteFG%, HiLiteBG%, MaxScrRows%, MaxScrCols%, ColumnPointer%, TweenSpace%, TableULRow%, TableULCol%, CurrentRow%, CurrentCol%, ItemNum%, ItemWidth%, FKey$, ExitCode%)
    DECLARE SUB SaveRestScrn (ReadLine$(), ReadColr%(), SR.UL.Row%, SR.UL.Col%, SR.LR.Row%, SR.LR.Col%, SaveOrRest%)
    '-----------------------------------------------------------------------


    '------<BoxBoy window routine - see SUB BoxBoy>-----------------------
    Title$ = "Page Directory.  Contains 25 Pages Of Important Notes."
    ULRow% = 3
    ULCol% = 8
    LRRow% = 18
    LRCol% = 68
    TitleRow% = 4
    TitleCol% = 13
    TitColrFor% = 1
    TitColrBak% = 7
    BoxColrFor% = 0
    BoxColrBak% = 7
    BoxStyle% = 2
    Shadow% = 1
    ShadowColr% = 8
    ClearColr% = 1
    CALL BoxBoy(Title$, ULRow%, ULCol%, LRRow%, LRCol%, TitleRow%, TitleCol%, TitColrFor%, TitColrBak%, BoxColrFor%, BoxColrBak%, BoxStyle%, Shadow%, ShadowColr%, ClearColr%)
    LOCATE 4, 37: COLOR 15, 7: PRINT Exten$: COLOR 0, 7
    line$ = CHR$(199) + STRING$(60, CHR$(196)) + CHR$(182)
    LOCATE 16, 9: PRINT line$;
    COLOR 1, 7
    LOCATE 17, 12: PRINT "Press <Enter> To Read Page.";
    LOCATE 17, 19: COLOR 15, 7: PRINT "Enter";
    LOCATE 17, 43: COLOR 1, 7: PRINT "Press <F1> <F5> Or <F10>";
    COLOR 15, 7
    LOCATE 17, 50: PRINT "F1";
    LOCATE 17, 55: PRINT "F5";
    LOCATE 17, 63: PRINT "F10";
    COLOR 0, 7
    LOCATE 16, 41: PRINT CHR$(194);
    LOCATE 17, 41: PRINT CHR$(179);
    LOCATE 18, 41: PRINT CHR$(207);
    CALL BoxBoy("", 21, 8, 23, 68, 1, 1, 1, 1, 15, 4, 2, 1, 8, 1000)
    COLOR 15, 4: LOCATE 22, 16
    PRINT "MOVE:  <" + CHR$(24) + "> <" + CHR$(25) + "> <" + CHR$(27) + "> <" + CHR$(26) + "> <Home> <End> <Esc> Aborts";
    COLOR 11, 4
    LOCATE 22, 24: PRINT CHR$(24); : LOCATE 22, 28: PRINT CHR$(25);
    LOCATE 22, 32: PRINT CHR$(27); : LOCATE 22, 36: PRINT CHR$(26);
    LOCATE 22, 40: PRINT "Home": LOCATE 22, 47: PRINT "End";
    LOCATE 22, 53: PRINT "Esc";

    REDIM M$(26)
     M$(1) = "Page One"
     M$(2) = "Page Two"
     M$(3) = "Page Three"
     M$(4) = "Page Four"
     M$(5) = "Page Five"
     M$(6) = "Page Six"
     M$(7) = "Page Seven"
     M$(8) = "Page Eight"
     M$(9) = "Page Nine"
    M$(10) = "Page Ten"
    M$(11) = "Page Eleven"
    M$(12) = "Page Twelve"
    M$(13) = "Page Thirteen"
    M$(14) = "Page Fourteen"
    M$(15) = "Page Fifteen"
    M$(16) = "Page Sixteen"
    M$(17) = "Page Seventeen"
    M$(18) = "Page Eighteen"
    M$(19) = "Page Nineteen"
    M$(20) = "Page Twenty"
    M$(21) = "Page Twenty-One"
    M$(22) = "Page Twenty-Two"
    M$(23) = "Page Twenty-Three"
    M$(24) = "Page Twenty-Four"
    M$(25) = "Page Twenty-Five"
                                
    '------<MesaMenu routine - See SUB MesaMenu>--------------------------
    Start% = 1                  ' <- <- put Start% above "top"
top:                            '
    Count% = 25                 '
    RegColrFG% = 0              '
    RegColrBG% = 7              '
    HiLiteFG% = 15              '
    HiLiteBG% = 0               ' +--------------------------------------+
    MaxScrRows% = 10            ' |  For an explanation of the items to  |
    MaxScrCols% = 4             ' |  the left, visit the SUB MesaMenu.   |
    ColumnPointer% = 1          ' |                                      |
    TweenSpace% = 2             ' +--------------------------------------+
    TableULRow% = 6             '
    TableULCol% = 13            '
    CurrentRow% = 0             '
    CurrentCol% = 0             '
    ItemNum% = Start%           '
    ItemWidth% = 17             '
    FKey$ = "150"               '

begin.complete.menu:
    CALL MesaMenu(M$(), Start%, Count%, RegColrFG%, RegColrBG%, HiLiteFG%, HiLiteBG%, MaxScrRows%, MaxScrCols%, ColumnPointer%, TweenSpace%, TableULRow%, TableULCol%, CurrentRow%, CurrentCol%, ItemNum%, ItemWidth%, FKey$, ExitCode%)
    IF ExitCode% = 27 THEN                           '<Esc>
        COLOR 7, 0: CLS : LOCATE 1, 1, 1, 6, 7: END
        '<F1> <F5> <F10> <Enter>
    ELSEIF ExitCode% = 1 OR ExitCode% = 5 OR ExitCode% = 10 OR ExitCode% = 13 THEN
        GOSUB save.screen
        COLOR 15, 2: CLS
        CALL BoxBoy("", 8, 20, 16, 60, 1, 1, 1, 1, 15, 2, 1, 0, 8, 1000)
        COLOR 15, 2
        LOCATE 10, 30: PRINT "ExitCode% Was" + STR$(ExitCode%) + "."
        IF ExitCode% = 1 OR ExitCode% = 5 OR ExitCode% = 10 THEN
            LOCATE 12, 30: PRINT "<F" + RTRIM$(LTRIM$(STR$(ExitCode%))) + "> Was Pressed."
        ELSEIF ExitCode% = 13 THEN
            LOCATE 12, 30: PRINT RTRIM$(LTRIM$(M$(ItemNum%))) + " Was Pressed."
        END IF
        LOCATE 14, 30: PRINT "Press Any Key To Continue."
        DO: LOOP WHILE INKEY$ = ""
        GOSUB restore.screen
        Start% = ItemNum%
        GOTO begin.complete.menu
    ELSE
        GOTO begin.complete.menu
    END IF

save.screen:
    REDIM ReadLine$(25)
    REDIM ReadColr%(25, 80)
    SR.UL.Row% = 1
    SR.UL.Col% = 1
    SR.LR.Row% = 25
    SR.LR.Col% = 80
    SaveOrRest% = 1
    CALL SaveRestScrn(ReadLine$(), ReadColr%(), SR.UL.Row%, SR.UL.Col%, SR.LR.Row%, SR.LR.Col%, SaveOrRest%)
    RETURN

restore.screen:
    SR.UL.Row% = 1
    SR.UL.Col% = 1
    SR.LR.Row% = 25
    SR.LR.Col% = 80
    SaveOrRest% = 2
    CALL SaveRestScrn(ReadLine$(), ReadColr%(), SR.UL.Row%, SR.UL.Col%, SR.LR.Row%, SR.LR.Col%, SaveOrRest%)
    ERASE ReadLine$: ERASE ReadColr%
    RETURN

SUB BoxBoy (Title$, ULRow%, ULCol%, LRRow%, LRCol%, TitleRow%, TitleCol%, TitColrFor%, TitColrBak%, BoxColrFor%, BoxColrBak%, BoxStyle%, Shadow%, ShadowColr%, ClearColr%)

    '+---------------------------------------------------------------------+
    '|                          SUB BoxBoy                                 |
    '+---------------------------------------------------------------------+
    '| SUB written by Don Smith on March 25, 2002.  Declared Public        |
    '| Domain FreeWare.   Other programmers may use this SUB without       |
    '| naming me as the author.  Don's EMail: smithdonb@earthlink.net      |
    '|                                                                     |
    '| This SUB only saves the underlying screen to repaint with a shadow. |
    '| So recommend using the SUB SaveRestScrn to save/restore screen.     |
    '| Please read: SUB SaveRestScrn.                                      |
    '+-------------+-------------------------------------------------------+
    '| Title$      | The title of the menu.  To make a box without a title,|
    '|             | use: Title$ = "".  When there is no Title, the cross  |
    '|             | bar is not deployed.                                  |
    '|-------------+-------------------------------------------------------|
    '| ULRow%      | The upper left row to place the box.                  |
    '|-------------+-------------------------------------------------------|
    '| ULCol%      | The upper left column to place the box.               |
    '|-------------+-------------------------------------------------------|
    '| LRRow%      | The lower right row to place the box.                 |
    '|-------------+-------------------------------------------------------|
    '| LRCol%      | The lower right column to place the box.              |
    '|-------------+----------------------------------+--------------------|
    '| TitleRow%   | The row to place the title.      | If there is to be  |
    '|-------------+----------------------------------| NO title, these 4  |
    '| TitleCol%   | The column to place the title.   | values will be     |
    '|-------------+----------------------------------| ignored.  If that  |
    '| TitColrFor% | The foreground color of the title| is the case, these |
    '|-------------+----------------------------------| values may be      |
    '| TitColrBak% | The background color of the title| omitted.           |
    '|-------------+----------------------------------+--------------------|
    '| BoxColrFor% | The foreground color of the box itself.               |
    '|-------------+-------------------------------------------------------|
    '| BoxColrBak% | The back ground color of the box.                     |
    '+-------------+-------------------------------------------------------+
    '| Style%      | Style% equals 1 - Single line around box              |
    '|             | Style% equals 2 - Double line around box              |
    '+-------------+-------------------------------------------------------+
    '| Shadow%     | If Shadow% equals 0, there will be no shadow .        |
    '|             | If Shadow% equals 1, there will be a right shadow.    |
    '|             | If Shadow% equals 2, there will be a left shadow      |
    '|             +-------------------------------------------------------+
    '|             | NOTE #1:                                              |
    '|             | -------                                               |
    '|             | When a shadow is used, the underlying text will       |
    '|             | be saved and printed with COLOR 8, 0 (very dim).      |              |
    '|             | This causes the shadow to look like a real shadow.    |
    '|             |                                                       |
    '|             | NOTE #2:                                              |
    '|             | -------                                               |
    '|             | If the first four values of BoxBoy are 1, 1, 25, 89,  |
    '|             | in other words a full screen, please set Shadow% = 0  |
    '|             | otherwise an error will result (no room for shadow).  |
    '+-------------+-------------------------------------------------------+
    '| ShadeColr%  |  The foreground color of the shadow.   Usually        |
    '|             |  this color is 8 or 7 (Normally 8).                   |      |
    '+-------------+-------------------------------------------------------+
    '| ClearColr%  |  What color (0-7) to clear screen before making box.  |
    '|             |  To disable this feature, use ClearColr% = 1000       |
    '|             |                                                       |
    '|             |                   COLOR VALUES:                       |
    '|             |         ----------------------------------            |
    '|             |         0 is black         4 is red                   |
    '|             |         1 is blue          5 is purple                |
    '|             |         2 is green         6 is orange                |
    '|             |         3 is light blue    7 is light white           |
    '|             |                                                       |
    '+-------------+-------------------------------------------------------+
   
    IF ClearColr% <> 1000 THEN
        COLOR , ClearColr%: CLS
    END IF

    IF ULCol% <= 1 THEN
       ULCol% = 1
    END IF
    IF LRCol% = 80 THEN
       LRCol% = 77
    END IF
    
make.box:
    IF BoxStyle% = 1 THEN           'Single Line
        ULCorner$ = CHR$(218)
        URCorner$ = CHR$(191)
        HorLine$ = CHR$(196)
        LeftSide$ = CHR$(195)
        RightSide$ = CHR$(180)
        VertLine$ = CHR$(179)
        LLCorner$ = CHR$(192)
        LRCorner$ = CHR$(217)
    ELSEIF BoxStyle% = 2 THEN      'Double Line
        ULCorner$ = CHR$(201)
        URCorner$ = CHR$(187)
        HorLine$ = CHR$(205)
        LeftSide$ = CHR$(199)
        RightSide$ = CHR$(182)
        VertLine$ = CHR$(186)
        LLCorner$ = CHR$(200)
        LRCorner$ = CHR$(188)
    END IF
   
    IF Shadow% = 1 THEN
        REDIM ReadLine$(25)
        FOR ViewIt% = ULRow% + 1 TO LRRow% + 1
            FOR Horizon% = ULCol% + 2 TO LRCol% + 5
                ReadLine$(ViewIt%) = ReadLine$(ViewIt%) + CHR$(SCREEN(ViewIt%, Horizon%))
            NEXT
        NEXT
        COLOR ShadowColr%, 0
        FOR Scratch% = ULRow% + 1 TO LRRow% + 1
            LOCATE Scratch%, ULCol% + 2
            PRINT ReadLine$(Scratch%);
        NEXT
    ELSEIF Shadow% = 2 THEN
        REDIM ReadLine$(25)
        FOR ViewIt% = ULRow% + 1 TO LRRow% + 1
            FOR Horizon% = ULCol% - 2 TO LRCol% + 1
                ReadLine$(ViewIt%) = ReadLine$(ViewIt%) + CHR$(SCREEN(ViewIt%, Horizon%))
            NEXT
        NEXT
        COLOR ShadowColr%, 0
        FOR Scratch% = ULRow% + 1 TO LRRow% + 1
            LOCATE Scratch%, ULCol% - 2
            PRINT ReadLine$(Scratch%);
        NEXT
    END IF

    Title.Length% = LEN(Title$)
    COLOR BoxColrFor%, BoxColrBak%
    'ÚÄÄÄ¿   or  ÉÍÍÍ»
    LOCATE ULRow%, ULCol%
    PRINT " " + ULCorner$ + STRING$(LRCol% - ULCol%, HorLine$) + URCorner$ + " ";

    '³   ³   or  º   º
    LOCATE ULRow% + 1, ULCol%
    PRINT " " + VertLine$ + SPACE$(LRCol% - ULCol%) + VertLine$ + " ";
   
    IF Title$ <> "" THEN
        'ÃÄÄÄ´   or  ÇÄÄĶ         'made cross bar if there is a title
        LOCATE ULRow% + 2, ULCol%
        PRINT " " + LeftSide$ + STRING$(LRCol% - ULCol%, 196) + RightSide$ + " ";
    ELSEIF Title$ = "" THEN
        LOCATE ULRow% + 2, ULCol%
        PRINT " " + VertLine$ + SPACE$(LRCol% - ULCol%) + VertLine$ + " ";
    END IF
   
    '³   ³   or  º   º
    FOR Print.Box% = 1 TO (LRRow% - ULRow%) - 3
        LOCATE ULRow% + Print.Box% + 2, ULCol%
        PRINT " " + VertLine$ + SPACE$(LRCol% - ULCol%) + VertLine$ + " ";
    NEXT

    'ÀÄÄÄÙ  or  ÈÍÍͼ
    LOCATE LRRow%, ULCol%, 0
    PRINT " " + LLCorner$ + STRING$(LRCol% - ULCol%, HorLine$) + LRCorner$ + " ";
    IF Title$ <> "" THEN
        LOCATE TitleRow%, TitleCol%
        COLOR TitColrFor%, TitColrBak%
        PRINT Title$;
    END IF

END SUB

SUB MesaMenu (M$(), Start%, Count%, RegColrFG%, RegColrBG%, HiLiteFG%, HiLiteBG%, MaxScrRows%, MaxScrCols%, ColumnPointer%, TweenSpace%, TableULRow%, TableULCol%, CurrentRow%, CurrentCol%, ItemNum%, ItemWidth%, FKey$, ExitCode%)

    ' +--------------------------------------------------------------------+
    ' |                                                                    |
    ' |               -  S U B: M e s a M e n u  -                         |
    ' |                                                                    |
    ' |                  Public Domain - FreeWare                          |
    ' +--------------------------------------------------------------------+
    ' | MesaMenu was created by Don Smith on 08/01/2002.  MesaMenu is      |
    ' | declared Public Domain FreeWare.                                   |
    ' |           - - - - - - - - - - - - - - - - - - - - - - - -          |
    ' | The MesaMenu name is abbreviated as MM to make it easier to        |
    ' | enter at the command prompt.                                       |
    ' |           - - - - - - - - - - - - - - - - - - - - - - - -          |
    ' | The object of MesaMenu is to display on screen a table menu        |
    ' | of selected files on the current directory. When MM.Exe is used    |
    ' | by itself instead of as a SUB, then enter as a parameter a group   |
    ' | of files which have a common extension.  Example: "MM *.txt"       |
    ' | (without quotes) For this example, MesaMenu will bring up in a     |
    ' | viewing window all files on the current directory having the       |
    ' | extension of .TXT. To view ALL the files on the current directory, |
    ' | use "MM *.*" To view all your QuickBASIC files, use "MM *.bas"     |
    ' | To view files having no extension, use "MM *."                     |
    ' |           - - - - - - - - - - - - - - - - - - - - - - - -          |
    ' | The program user may move the block cursor by pressing: <UpArrow>  |
    ' | <DnArrow> <RightArrow> <LeftArrow> <Home> <End> <PgDn> <PgUp>.  In |
    ' | addition, the user may press a letter, a number, an exclamation    |
    ' | <Shift> <!>, or an underline <Shift> <_>.   The hi-lite cursor     |
    ' | will jump to the first item beginning with the letter pressed,     |
    ' | and, if there are any more items beginning with that letter, it    |
    ' | will move down at each press of that letter.  This SUB is not      |
    ' | set up to use a mouse.                                             |
    ' +----------------+---------------------------------------------------+
    ' | M$()           | Menu Item.  In main program rediminsion:          |
    ' |                |             REDIM M$(MaxNum% + 10)                |
    ' +----------------+---------------------------------------------------+
    ' | Start%         | Which item to hi-light first.                     |
    ' +----------------+---------------------------------------------------+
    ' | Count%         | Count of total menu items.                        |
    ' +----------------+---------------------------------------------------+
    ' | RegColrFG%     | Regular fore ground color.                        |
    ' +----------------+---------------------------------------------------+
    ' | RegColrBG%     | Regular background color.                         |
    ' +----------------+---------------------------------------------------+
    ' | HiLiteFG%      | Hi-light foreground color.                        |
    ' +----------------+---------------------------------------------------+
    ' | HiLiteBG%      | Hi-light background color.                        |
    ' +----------------+---------------------------------------------------+
    ' | MaxScrRows%    | Number of rows to display on screen.              |
    ' +----------------+---------------------------------------------------+
    ' | MaxScrCols%    | Number of columns to display on screen.           |
    ' +----------------+---------------------------------------------------+
    ' | ColumnPointer% | Points to current column in use.                  |
    ' +----------------+---------------------------------------------------+
    ' | TweenSpace%    | Number of spaces between columns.                 |
    ' +----------------+---------------------------------------------------+
    ' | TableULRow%    | Upper left row to place menu.                     |
    ' +----------------+---------------------------------------------------+
    ' | TableULCol%    | Upper left column to place menu.                  |
    ' +----------------+---------------------------------------------------+
    ' | CurrentRow%    | Current row of hi-light item.                     |
    ' +----------------+---------------------------------------------------+
    ' | CurrentCol%    | Current column of hi-light item.                  |
    ' +----------------+---------------------------------------------------+
    ' | ItemNum%       | Menu item number of the hi-lighted item.          |
    ' |                | In main program Start% and ItemNum% should be     |
    ' |                | the same.                                         |
    ' +----------------+---------------------------------------------------+
    ' | ItemWidth%     | Width of menu items.                              |
    ' +----------------+---------------------------------------------------+
    ' | FKey$          | To exit when an <F> key is pressed, designate     |
    ' |                | the <F> keys by placing them between paranthesis. |
    ' |                | Example: FKey$ = "150". This means the SUB will   |
    ' |                | exit on pressing <F1>, <F5> or <F10>.  The "0"    |
    ' |                | means "10". In the main program, indicate the     |
    ' |                | <F> keys with ExitCode%.  <F1> to <F10> is        |
    ' |                | ExitCode% = 1 to ExitCode% = 10.                  |
    ' |                |                                                   |
    ' |                | Example:                                          |
    ' |                | -------                                           |
    ' |                |             IF ExitCode% = 1 THEN  '<F1>          |
    ' |                |                 GOSUB save.screen                 |
    ' |                |                 COLOR 15, 1: CLS                  |
    ' |                |                 LOCATE 2, 33                      |
    ' |                |                 PRINT "Help Screen"               |
    ' |                |                 DO: LOOP WHILE INKEY$ = ""        |
    ' |                |                 GOSUB restore.screen              |
    ' |                |                 Start% = ItemNum%                 |
    ' |                |                 GOTO begin.complete.menu          |
    ' |                |             END IF                                |
    ' +----------------+---------------------------------------------------+
    ' | ExitCode%      | The exit number as explained below.               |
    ' +--------------------------------------------------------------------+
    ' | In the code below this REM (') section, find the area beginning    |
    ' | "loopdeloop" and notice the keys trap below it.   In QuickBASIC    |
    ' | it is very easy to trap for any key on the keyboard by using the   |
    ' | CVI command.  It is accomplished through  the use of a double      |
    ' | DO/LOOP and then a series of IF/THENs (See Example).               |
    ' |                                                                    |
    ' |         Example:                                                   |
    ' |         -------                                                    |
    ' |         COLOR 15, 1: CLS                                           |
    ' |         PRINT "Press <F1> or <Ctrl> X.   To exit, press <Esc>"     |
    ' |         PRINT                                                      |
    ' |         DO                                                         |
    ' |             DO                                                     |
    ' |                 Hit$ = INKEY$                                      |
    ' |             LOOP UNTIL LEN(Hit$) > 0                               |
    ' |             Hit% = CVI(Hit$ + CHR$(0))                             |
    ' |             IF Hit% = 27 THEN          '<Esc>                      |
    ' |                 CLS : END                                          |
    ' |             ELSEIF Hit% = 15104 THEN   '<F1>                       |
    ' |                 PRINT "F1 - Yeah!"                                 |
    ' |             ELSEIF Hit% = 24 THEN      '<Ctrl> <X> or <Ctrl> <x>   |
    ' |                 PRINT "Ctrl-X.  Yeah!"                             |
    ' |             END IF                                                 |
    ' |         LOOP                                                       |
    ' |                                                                    |
    ' +--------------------------------------------------------------------+
    ' | Use KeyCode.Bas below to find out what the CVI numbers will be     |
    ' | for keys you wish to trap.                                         |
    ' +--------------------------------------------------------------------+
    ' | '  KeyCode.Bas - By Don Smith. FreeWare and Public Domain Program. |
    ' | '                                                                  |
    ' | ' +-------------------------------------------------------------+  |
    ' | ' | Note:  To reach the extended ASCII characters 127 to 255,   |  |
    ' | ' |        press down on the <Alt> key, and while pressed down, |  |
    ' | ' |        type in the number on your keypad, not the numbers   |  |
    ' | ' |        above then <F> keys.                                 |  |
    ' | ' +-------------------------------------------------------------+  |
    ' |                                                                    |
    ' | COLOR 15, 1: CLS                                                   |
    ' | LOCATE 2, 16                                                       |
    ' | PRINT "Press a key and the CVI value will be displayed."           |
    ' | LOCATE 4, 28                                                       |
    ' | PRINT "(Press <Esc> To Quit"                                       |
    ' | LOCATE 5, 16: PRINT STRING$(47, "-")                               |
    ' | LOCATE 6, 24: LOCATE , , 1, 6, 7                                   |
    ' | DO                                                                 |
    ' |     DO                                                             |
    ' |         k$ = INKEY$                                                |
    ' |         IF k$ = CHR$(27) THEN                                      |
    ' |             LOCATE , 16                                            |
    ' |             PRINT STRING$(47, "-")                                 |
    ' |             LOCATE , 34: PRINT "Program Ends": PRINT : PRINT       |
    ' |             END                                                    |
    ' |         END IF                                                     |
    ' |     LOOP UNTIL k$ <> ""                                            |
    ' |     KeyCode% = CVI(k$ + CHR$(0))                                   |
    ' |     Key$ = STR$(KeyCode%)                                          |
    ' |     Sp$ = STRING$(9, ".")                                          |
    ' |     IF KeyCode% = 13 THEN                                          |
    ' |         LOCATE , 31, 0, 0, 0                                       |
    ' |         PRINT "Enter" + Sp$ + Key$                                 |
    ' |     ELSEIF KeyCode% = 255 THEN                                     |
    ' |         LOCATE , 25, 0, 0, 0                                       |
    ' |         PRINT "Blank Space" + Sp$ + Key$                           |
    ' |     ELSEIF KeyCode% < 256 THEN                                     |
    ' |         LOCATE , 35, 0, 0, 0                                       |
    ' |         PRINT k$ + Sp$ + Key$                                      |
    ' |     ELSEIF KeyCode% > 255 THEN                                     |
    ' |         LOCATE , 24, 0, 0, 0                                       |
    ' |         PRINT "Extended Key" + Sp$ + Key$                          |
    ' |     END IF                                                         |
    ' | LOOP                                                               |
    ' |                                                                    |
    ' +--------------------------------------------------------------------+
    
    FOR EqWidth% = 1 TO Count%    'make all M$ items of equal length
        M$(EqWidth%) = M$(EqWidth%) + SPACE$(ItemWidth% - LEN(M$(EqWidth%)))
    NEXT

subtop:
    DivideIt% = Count% \ MaxScrRows%
    Remainder% = Count% MOD MaxScrRows%
    IF Remainder% > 0 THEN
        Remainder% = 1
    END IF
    NumColsPossible% = DivideIt% + Remainder%
    LeftOver% = Count% MOD MaxScrRows%           'Count of items of last row
    IF Start% = 1 THEN
        CurrentRow% = TableULRow%
        CurrentCol% = TableULCol%
        ColumnPointer% = 1
    ELSE
        LocateRow% = Start% MOD MaxScrRows%
        IF LocateRow% = 0 THEN
            LocateRow% = MaxScrRows%
            ColumnPointer% = (Start% \ MaxScrRows%)
        ELSE
            ColumnPointer% = (Start% \ MaxScrRows%) + 1
        END IF
        CurrentRow% = TableULRow% + LocateRow% - 1
        LocateCol% = (Start% \ MaxScrRows%)
        IF Start% MOD MaxScrRows% > 0 THEN
            LocateCol% = LocateCol% + 1
        END IF
        IF LocateCol% > MaxScrCols% THEN
            LocateCol% = LocateCol% - MaxScrCols%
            FOR Spy% = 1 TO NumColsPossible%
                IF LocateCol% > MaxScrCols% THEN
                    LocateCol% = LocateCol% - MaxScrCols%
                END IF
                IF LocateCol% <= MaxScrCols% THEN
                    EXIT FOR
                END IF
            NEXT
            TheFactor% = ColumnPointer% \ MaxScrCols%
            IF ColumnPointer% MOD MaxScrCols% = 0 THEN
                show% = (MaxScrCols% * MaxScrRows%) * (TheFactor% - 1)
            ELSE
                show% = (MaxScrCols% * MaxScrRows%) * TheFactor%
            END IF
            IF LocateCol% <= 1 THEN
                CurrentCol% = TableULCol%
            END IF
        END IF
    END IF
    IF CurrentCol% < TableULCol% THEN
        CurrentCol% = TableULCol% + ((LocateCol% - 1) * (ItemWidth% + TweenSpace%))
    END IF
bring.in.display:
    FOR Display% = TableULRow% TO TableULRow% + MaxScrRows% - 1
        COLOR RegColrFG%, RegColrBG%
        LOCATE Display%, TableULCol%
        show% = show% + 1
        IF show% <= Count% THEN
            PRINT M$(show%) + SPACE$(TweenSpace%);
        ELSE
            PRINT SPACE$(ItemWidth% + TweenSpace%);
        END IF
        FOR ExecuteNext% = 1 TO MaxScrCols% - 1
            IF show% + (ExecuteNext% * MaxScrRows%) <= Count% THEN
                IF LEN(M$(show% + (ExecuteNext% * MaxScrRows%))) = ItemWidth% THEN
                    PRINT M$(show% + (ExecuteNext% * MaxScrRows%)) + SPACE$(TweenSpace%);
                ELSEIF LEN(M$(show% + (ExecuteNext% * MaxScrRows%))) = 0 THEN
                    PRINT SPACE$(ItemWidth% + TweenSpace%);
                END IF
            ELSE
                IF Count% > (MaxScrRows% * MaxScrCols%) THEN
                    PRINT SPACE$(ItemWidth% + TweenSpace%);
                END IF
            END IF
        NEXT
    NEXT
    COLOR HiLiteFG%, HiLiteBG%
    LOCATE CurrentRow%, CurrentCol%, 0
    PRINT M$(ItemNum%)
loopdeloop:
    DO
        DO
            HitKey$ = INKEY$
        LOOP UNTIL LEN(HitKey$) > 0
        Hit% = CVI(HitKey$ + CHR$(0))
        LOCATE CurrentRow%, CurrentCol%
        COLOR RegColrFG%, RegColrBG%
        PRINT M$(ItemNum%);
        IF Hit% = 27 THEN                                  '<Esc>
            ExitCode% = 27
            EXIT SUB
        ELSEIF Hit% = 13 THEN                              '<Enter>
            ExitCode% = 13
            EXIT SUB
        ELSEIF Hit% = 20480 THEN                           '<Down Arrow>
            IF LeftOver% = 0 AND ItemNum% = Count% THEN
                CurrentRow% = TableULRow% - 1
                ItemNum% = Count% - MaxScrRows%
            END IF
            IF ItemNum% < Count% THEN
                CurrentRow% = CurrentRow% + 1
                ItemNum% = ItemNum% + 1
                IF CurrentRow% = TableULRow% + MaxScrRows% THEN
                    CurrentRow% = TableULRow%
                    ItemNum% = ItemNum% - MaxScrRows%
                END IF
            ELSE
                CurrentRow% = TableULRow%
                ItemNum% = Count% - LeftOver% + 1
            END IF
        ELSEIF Hit% = 18432 THEN                           '<Up Arrow>
            CurrentRow% = CurrentRow% - 1
            ItemNum% = ItemNum% - 1
            IF CurrentRow% = TableULRow% - 1 THEN
                 CurrentRow% = TableULRow% + MaxScrRows% - 1
                 ItemNum% = ItemNum% + MaxScrRows%
                 IF ItemNum% > Count% THEN
                     ItemNum% = Count%
                     CurrentRow% = TableULRow% + LeftOver% - 1
                 END IF
            END IF
        ELSEIF Hit% = 19712 THEN                           '<Right Arrow>
            IF ItemNum% <= Count% - LeftOver% THEN
                CurrentCol% = CurrentCol% + TweenSpace% + ItemWidth%
                ItemNum% = ItemNum% + MaxScrRows%
                ColumnPointer% = ColumnPointer% + 1
                IF ItemNum% > Count% THEN
                    ItemNum% = Count%
                    IF LeftOver% = 0 THEN
                        CurrentCol% = CurrentCol% - (TweenSpace% + ItemWidth%)
                        CurrentRow% = TableULRow% + MaxScrRows% - 1
                        ItemNum% = Count%
                        ColumnPointer% = ColumnPointer% - 1
                    ELSEIF LeftOver% > 0 THEN
                        CurrentRow% = TableULRow% + LeftOver% - 1
                    END IF
                END IF
            END IF
            IF ColumnPointer% > MaxScrCols% THEN
                Start% = ItemNum%
                show% = 0
                ColumnPointer% = 0
                GOTO subtop
            END IF
        ELSEIF Hit% = 19200 THEN                           '<Left Arrow>
            IF ColumnPointer% <= 0 THEN
                ColumnPointer% = 1
            END IF
            IF ColumnPointer% > 1 THEN
                CurrentCol% = CurrentCol% - (TweenSpace% + ItemWidth%)
                ItemNum% = ItemNum% - MaxScrRows%
                ColumnPointer% = ColumnPointer% - 1
            END IF
            IF ColumnPointer% >= MaxScrCols% THEN
                ColumnPointer% = 0
                Start% = ItemNum%
                show% = 0
                GOTO subtop
            END IF
        ELSEIF Hit% = 18176 THEN                           '<Home>
            CurrentRow% = 0
            CurrentCol% = 0
            show% = 0
            ItemNum% = 1
            Start% = 1
            GOTO subtop
        ELSEIF Hit% = 20224 THEN                           '<End>
            show% = 0
            ItemNum% = Count%
            Start% = Count%
            CurrentCol% = 0
            GOTO subtop
        ELSEIF Hit% = 20736 THEN                           '<PgDn>
            ItemNum% = ItemNum% + (MaxScrRows% * MaxScrCols%)
            IF ItemNum% > Count% THEN
                ItemNum% = Count%
            END IF
            Start% = ItemNum%
            CurrentCol% = 0
            show% = 0
            GOTO subtop
        ELSEIF Hit% = 18688 THEN                           '<PgUp>
            ItemNum% = ItemNum% - (MaxScrRows% * MaxScrCols%)
            IF ItemNum% <= 0 THEN
                ItemNum% = 1
            END IF
            Start% = ItemNum%
            CurrentCol% = 0
            show% = 0
            GOTO subtop
        ELSEIF Hit% = 32 THEN                              '<Space Bar>
            ExitCode% = 32
            EXIT SUB
        'PRESS:   Letters A - Z (or a - z), Numbers 0 - 9,
        '         Exclamation <Shift><!>, or Underline <Shift><_>.
        ELSEIF Hit% > 64 AND Hit% < 91 OR Hit% > 96 AND Hit% < 123 OR Hit% > 47 AND Hit% < 58 OR Hit% = 33 OR Hit% = 95 THEN
            IF Hit% > 96 AND Hit% < 123 THEN
                Hit% = Hit% - 32
            END IF
            FOR XYZ% = 1 TO Count%
                Letr$ = LEFT$(M$(XYZ%), 1)
                IF XYZ% = Count% AND ASC(Letr$) <> Hit% THEN
                    show% = 0
                    GOTO subtop
                ELSEIF ASC(Letr$) = Hit% THEN
                    EXIT FOR
                END IF
            NEXT
            FOR YYY% = 1 TO Count%
                CurrentLetr$ = LEFT$(M$(ItemNum%), 1)
                IF CurrentLetr$ <> FindLetr$ THEN
                    TryLetters% = 0
                END IF
            NEXT
            TryLetters% = TryLetters% + 1
            FOR zzz% = TryLetters% TO Count%
                FindLetr$ = LEFT$(M$(zzz%), 1)
                IF ASC(FindLetr$) = Hit% THEN
                    Start% = zzz%
                    TryLetters% = zzz%
                    ItemNum% = Start%
                    ColumnPointer% = 0
                    show% = 0
                    CurrentCol% = 0
                    IF zzz% = Count% THEN
                        ItemNum% = Count%
                        TryLetters% = 0
                    END IF
                    GOTO subtop
                END IF
                IF zzz% = Count% THEN
                    zzz% = 0
                END IF
            NEXT
         ELSEIF Hit% > 15103 AND Hit% < 17409 THEN         'F1 - F10
             IdentKey$ = STR$(((Hit% - 15104) \ 256) + 1)
             IdentKey$ = LTRIM$(RTRIM$(IdentKey$))
             IF IdentKey$ = "10" THEN
                 IdentKey$ = "0"
             END IF
             IF INSTR(FKey$, IdentKey$) > 0 THEN
                 IF IdentKey$ = "0" THEN
                     ExitCode% = 10
                     EXIT SUB
                 ELSE
                     ExitCode% = VAL(IdentKey$)
                     EXIT SUB
                 END IF
             END IF
        END IF
        LOCATE CurrentRow%, CurrentCol%
        COLOR HiLiteFG%, HiLiteBG%
        PRINT M$(ItemNum%);
   LOOP

END SUB


SUB SaveRestScrn (ReadLine$(), ReadColr%(), SR.UL.Row%, SR.UL.Col%, SR.LR.Row%, SR.LR.Col%, SaveOrRest%)

    '+----------------------------------------------------------------------+
    '| SUB written by Don Smith on 03/25/02 - Public Domain FreeWare.       |
    '| No need to name Don as the author.   EMail: smithdonb@earthlink.net  |
    '+----------------------------------------------------------------------+

    '+----------------------------------------------------------------------+
    '|                    PROGRAM SETS NUMBERS 1 AND 2 ->                   |
    '+------------------+---------------------------------------------------+
    '| (1) ReadLine$()  |   Program self reads data at each Row and Column  |
    '+------------------+---------------------------------------------------+
    '| (2) ReadColr%()  |   Program self reads color at each Row and Column |
    '+------------------+---------------------------------------------------+

    '+----------------------------------------------------------------------+
    '|            THE PROGRAMMER MUST SET NUMBERS 3 TO 9 ->                 |
    '+----------------------------------------------------------------------+
    '|       (Note: The "SR" below means "Save" Or "Restore")               |
    '+------------------+---------------------------------------------------+
    '| (3) SR.UL.Row%   |   Screen to save or restore at upper left row.    |
    '| (4) SR.UL.Col%   |   Screen to save or restore at upper left column. |
    '| (5) SR.LR.Row%   |   Screen to save or restore at lower right row.   |
    '| (6) SR.LR.Col%   |   Screen to save or restore at lower right column.|
    '|                  +---------------------------------------------------+
    '|                  |   SPECIAL CAUTION:                                |
    '|                  |   ---------------                                 |
    '|                  |   When you call the SUB to restore the underlying |
    '|                  |   screen, use MUST use the same row and column    |
    '|                  |   numbers as you used when you first called the   |
    '|                  |   SUB to save the screen.                         |
    '+------------------+---------------------------------------------------+
    '| (7) SaveOrRest%  |   SaveOrRest% = 1 (1 means save the screen)       |
    '|                  |   SaveOrRest% = 2 (2 means restore the screen)    |
    '+------------------+----------+----------------------------------------+
    '| (8) REDIM ReadLine$(25)     | The REDIM for ReadLine$ and ReadColr%  |
    '|     REDIM ReadColr%(25, 80) | must be placed in the main program     |
    '|                             | before calling the SUB.  The 25 and 80 |
    '|                             | reflects a screen of 25 lines and 80   |
    '|                             | columns.  You may use smaller amounts  |
    '|                             | of memory if you do not need all 25    |
    '|                             | lines and 80 columns.                  |
    '+-----------------------------+----------------------------------------+
    '| (9) ERASE ReadLine$         | Reclaim memory after calling the SUB   |
    '|     ERASE ReadColr%         | to restore the screen.  Use REDIM and  |
    '|                             | ERASE in main program please!          |
    '+-----------------------------+----------------------------------------+

    IF SR.LR.Col% > 80 THEN
          SR.LR.Col% = 80
    END IF
    IF SR.LR.Row% > 25 THEN
          SR.LR.Row% = 25
    END IF

    IF SaveOrRest% = 1 THEN
          GOSUB save.da.screen
    ELSEIF SaveOrRest% = 2 THEN
          GOSUB restore.da.screen
    END IF
    EXIT SUB

save.da.screen:
    FOR ViewIt% = SR.UL.Row% TO SR.LR.Row%
          FOR Horizon% = SR.UL.Col% TO SR.LR.Col%
              ReadLine$(ViewIt%) = ReadLine$(ViewIt%) + CHR$(SCREEN(ViewIt%, Horizon%))
              ReadColr%(ViewIt%, Horizon%) = SCREEN(ViewIt%, Horizon%, 1)
          NEXT
    NEXT
    RETURN
restore.da.screen:
    FOR FindRow% = SR.UL.Row% TO SR.LR.Row%
          FOR ScrnCol% = SR.UL.Col% TO SR.LR.Col%
              LOCATE FindRow%, ScrnCol%, 0
              OneColr% = ReadColr%(FindRow%, ScrnCol%)
              FGScrnColr% = OneColr% MOD 16
              BGScrnColr% = OneColr% \ 16
              COLOR FGScrnColr%, BGScrnColr%
              PRINT MID$(ReadLine$(FindRow%), ScrnCol% - (SR.UL.Col% - 1));
          NEXT
    NEXT
    RETURN
END SUB