REM $DYNAMIC
SUB BoxBoy (Title$, ULRow%, ULCol%, LRRow%, LRCol%, TitleRow%, TitleCol%, TitColrFG%, TitColrBG%, BoxColrFG%, BoxColrBG%, BoxStyle%, Shadow%, ShadowColr%, EdgeYN%)
    ' +--------------------------------------------------------------------+
    ' |                    - S U B   B o x B o y -                         |
    ' |                                                                    |
    ' |                   Public Domain -  FreeWare                        |
    ' +--------------------------------------------------------------------+
    ' |  Author: Donald B. "Don" Smith                                     |
    ' |  Email : smithdonb@earthlink.net                                   |
    ' |  Date: 03/25/2002                                                  | 
    ' +--------------------------------------------------------------------+
    ' |                      - ABOUT THE AUTHOR -                          |
    ' +--------------------------------------------------------------------+
    ' |                                                                    |
    ' | Hello. My name is Don Smith and I am a thirty-year retired teacher |
    ' | of Math/History/Spanish residing in Orange County, California. I   |
    ' | am also a former six-year Sergeant of Marines. Who-Rah! On certain |
    ' | forums I am known as MarineDon.My email is: smithdonb@earthlink.net|
    ' |                                                                    |
    ' +--------------------------------------------------------------------+
    ' |                 - COPYING AND DISTIBUTING -                        |
    ' +--------------------------------------------------------------------+
    ' | Since this code is public domain and freeware, anyone may freely   |
    ' | copy and distribute it. If you use the QuickBasic code in one of   |
    ' | your own programs, you do not have to cite my name as the author,  |
    ' | and you may even change its name.                                  |
    ' +--------------------------------------------------------------------+
    ' | The SUB BoxBoy was written by Don Smith.   This BoxBoy is the      |
    ' | lastest iteration of the SUB - written 12-01-2002.   Other         |
    ' | programmers, or anyone else for that matter, may use this SUB      |
    ' | without naming me as the author, and they may modify the code      |
    ' | in any way they see fit.                                           |
    ' |                                                                    |
    ' |            Don's EMail: smithdonb@earthlink.net                    |
    ' |                                                                    |
    ' | This SUB only saves that portion of the underlying screen under    |
    ' | the box and repaints with a shadow.  So recommend using the SUB    |
    ' | SaveRestScrn to save/restore the complete screen, or a larger      |
    ' | portion of the screen than the box.                                |
    ' +-------------+------------------------------------------------------+
    ' | Title$      | The title of the menu. To make a box without a title,|
    ' |             | use: Title$ = "".  When there is no Title, the cross |
    ' |             | bar is not deployed.                                 |
    ' +-------------+------------------------------------------------------+
    ' | ULRow%      | The upper left row to place the box.                 |
    ' +-------------+------------------------------------------------------+
    ' | ULCol%      | The upper left column to place the box.              |
    ' +-------------+------------------------------------------------------+
    ' | LRRow%      | The lower right row to place the box.                |
    ' +-------------+------------------------------------------------------+
    ' | LRCol%      | The lower right column to place the box.             |
    ' +-------------+----------------------------------+-------------------+
    ' | TitleRow%   | The row to place the title.      | If Title$ = ""    |
    ' +-------------+----------------------------------| (or NO title),    |
    ' | TitleCol%   | The column to place the title.   | report these four |
    ' +-------------+----------------------------------| values as zero (0)|
    ' | TitColrFG%  | The foreground color of the title|  . . . . . . . .  |
    ' +-------------+----------------------------------| Example ->        |
    ' | TitColrBG%  | The background color of the title| TitColrFG% = 0    |
    ' +-------------+----------------------------------+-------------------+
    ' | BoxColrFG%  | The foreground color of the box itself.              |
    ' +-------------+------------------------------------------------------+
    ' | BoxColrBG%  | The back ground color of the box.                    |
    ' +-------------+------------------------------------------------------+
    ' | BoxStyle%   | BoxStyle% = 0 (No line around box)                   |
    ' |             | BoxStyle% = 1 (Single line around box                |
    ' |             | BoxStyle% = 2 (Double line around box                |
    ' |             | BoxStyle% = 3 (Solid line around box                 |
    ' +-------------+------------------------------------------------------+
    ' | Shadow%     | If Shadow% equals 0, there will be no shadow.        |
    ' |             | If Shadow% equals 1, there will be a right shadow.   |
    ' |             | If Shadow% equals 2, there will be a left shadow     |
    ' |             +------------------------------------------------------+
    ' |             | NOTE #1:                                             |
    ' |             | -------                                              |
    ' |             | When a shadow is used, the underlying text will      |
    ' |             | be saved and printed with the ShadeColr% (just       |
    ' |             | below).   This causes the shadow to look like a      |
    ' |             | real shadow.                                         |
    ' |             |                                                      |
    ' |             | NOTE #2:                                             |
    ' |             | -------                                              |
    ' |             | If the first four values of BoxBoy are 1, 1, 25, 80, |
    ' |             | in other words a full screen, please set Shadow% = 0;|
    ' |             | otherwise an error will result (no room for shadow). |
    ' +-------------+------------------------------------------------------+
    ' | ShadowColr% |  The ShadowColr% is the foreground color of the      |
    ' |             |  shadow.  The background color will always be        |
    ' |             |  black.  Either choose ShadowColr% = 7 or            |
    ' |             |  ShadowColr% = 8.                                    |
    ' |             |                                                      |
    ' |             |  ShadowColr% = 7 saves the foreground color and      |
    ' |             |  changes it to a shade darker, if possible.  For     |
    ' |             |  example, a bright white on blue (COLOR 15, 1)       |
    ' |             |  becomes dim white on black (COLOR 7, 0). A bright   |
    ' |             |  blue on blue (COLOR 9, 1) becomes regular blue      |
    ' |             |  on black (COLOR 1, 0).   Very realistic.            |
    ' |             |                                                      |
    ' |             |  ShadowColr% = 8 saves the foreground and reprints   |
    ' |             |  it as COLOR 8, 0.  Darker then ShadowColr% = 7      |
    ' +-------------+----------------+-------------------------------------+
    ' | EdgeYN%     |  EdgeYN% = 0   |  Do NOT print an edge of one space  |
    ' |             |                |  with BoxColrFG% color on the right |
    ' |             |                |  and left edges of the box.         |
    ' |             +----------------+-------------------------------------+
    ' |             |  EdgeYN% = 1   |  YES, DO print an edge of one space |
    ' |             |                |  with BoxColrFG% color on the right |
    ' |             |                |  and left edges of the box.         |
    ' |             +----------------+-------------------------------------+
    ' |             |  What does it mean to "print an edge of one space    |
    ' |             |  with BoxColrFG% color on the right and left edges   |
    ' |             |  of the box".   Well, I will attempt to demonstrate  |
    ' |             |  by drawing the boxes with non-extended ASCII        |
    ' |             |  characters.  The X's represent a shadow to the      |
    ' |             |  right.                                              |
    ' |             |                                                      |
    ' |             |    NO EDGE RIGHT/LEFT       1 SPACE EDGE RIGHT/LEFT  |
    ' |             |    ~~~~~~~~~~~~~~~~~~       ~~~~~~~~~~~~~~~~~~~~~~~  |
    ' |             |       (EdgeYN% = 0)              (EdgeYN% = 1        |
    ' |             |                                                      |
    ' |             |    +-----------------+      +-------------------+    |
    ' |             |    |+---------------+|      | +---------------+ |    |
    ' |             |    ||               ||XX    | |               | |XX  |
    ' |             |    ||               ||XX    | |               | |XX  |
    ' |             |    ||               ||XX    | |               | |XX  |
    ' |             |    ||               ||XX    | |               | |XX  |
    ' |             |    ||               ||XX    | |               | |XX  |
    ' |             |    ||               ||XX    | |               | |XX  |
    ' |             |    ||               ||XX    | |               | |XX  |
    ' |             |    |+---------------+|XX    | +---------------+ |XX  |
    ' |             |    +-----------------+XX    +-------------------+XX  |
    ' |             |      XXXXXXXXXXXXXXXXXXX      XXXXXXXXXXXXXXXXXXXXX  |
    ' |             |                                                      |
    ' +-------------+------------------------------------------------------+

    IF Title$ = "" THEN
        TitleRow% = 1: TitleCol% = 1: TitColrFG% = 1: TitColrBG% = 1
    END IF
    IF EdgeYN% > 1 OR EdgYN% < 0 THEN
        EdgeYN% = 0
    END IF

    IF ULCol% <= 1 THEN
       ULCol% = 1
    END IF
    IF LRCol% = 80 THEN
       LRCol% = 79
    END IF

make.box:
    IF BoxStyle% = 0 THEN              'No Lines
        ULCorner$ = CHR$(255)
        URCorner$ = CHR$(255)
        HorLineTop$ = CHR$(255)
        HorLineBot$ = CHR$(255)
        LeftSide$ = CHR$(255)
        RightSide$ = CHR$(255)
        VertLine$ = CHR$(255)
        LLCorner$ = CHR$(255)
        LRCorner$ = CHR$(255)
    ELSEIF BoxStyle% = 1 THEN          'Single Line
        ULCorner$ = CHR$(218)
        URCorner$ = CHR$(191)
        HorLineTop$ = CHR$(196)
        HorLineBot$ = CHR$(196)
        LeftSide$ = CHR$(195)
        RightSide$ = CHR$(180)
        VertLine$ = CHR$(179)
        LLCorner$ = CHR$(192)
        LRCorner$ = CHR$(217)
    ELSEIF BoxStyle% = 2 THEN          'Double Line
        ULCorner$ = CHR$(201)
        URCorner$ = CHR$(187)
        HorLineTop$ = CHR$(205)
        HorLineBot$ = CHR$(205)
        LeftSide$ = CHR$(199)
        RightSide$ = CHR$(182)
        VertLine$ = CHR$(186)
        LLCorner$ = CHR$(200)
        LRCorner$ = CHR$(188)
    ELSEIF BoxStyle% = 3 THEN          'Solid line
        ULCorner$ = CHR$(219)
        URCorner$ = CHR$(219)
        HorLineTop$ = CHR$(223)
        HorLineBot$ = CHR$(220)
        LeftSide$ = CHR$(219)
        RightSide$ = CHR$(219)
        VertLine$ = CHR$(219)
        LLCorner$ = CHR$(219)
        LRCorner$ = CHR$(219)
    END IF
    IF Shadow% > 0 THEN
        IF EdgeYN% = 1 THEN
            IF Shadow% = 1 THEN
                LeftLimit% = ULCol% + 2
                RightLimit% = LRCol% + 5
            ELSEIF Shadow% = 2 THEN
                LeftLimit% = ULCol% - 2
                RightLimit% = LRCol%
            END IF
        ELSEIF EdgeYN% = 0 THEN
            IF Shadow% = 1 THEN
                LeftLimit% = ULCol% + 2
                RightLimit% = LRCol% + 3
            ELSEIF Shadow% = 2 THEN
                LeftLimit% = ULCol% - 2
                RightLimit% = LRCol% - 1
            END IF
        END IF
        REDIM ReadLine$(25): REDIM ReadColr%(25, 80)

        FOR ViewIt% = ULRow% + 1 TO LRRow% + 1
              FOR Horizon% = LeftLimit% TO RightLimit%
                  ReadLine$(ViewIt%) = ReadLine$(ViewIt%) + CHR$(SCREEN(ViewIt%, Horizon%))
                  ReadColr%(ViewIt%, Horizon%) = SCREEN(ViewIt%, Horizon%, 1)
              NEXT
        NEXT
        FOR FindRow% = ULRow% + 1 TO LRRow% + 1
              FOR ScrnCol% = LeftLimit% TO RightLimit%
                  LOCATE FindRow%, ScrnCol%, 0
                  OneColr% = ReadColr%(FindRow%, ScrnCol%)
                  FGScrnColr% = OneColr% MOD 16
                 
                  'make colors less bright
                  IF FGScrnColr% = 0 THEN FGScrnColr% = 7
                  IF FGScrnColr% = 9 THEN FGScrnColr% = 1
                  IF FGScrnColr% = 10 THEN FGScrnColr% = 2
                  IF FGScrnColr% = 11 THEN FGScrnColr% = 3
                  IF FGScrnColr% = 12 THEN FGScrnColr% = 4
                  IF FGScrnColr% = 13 THEN FGScrnColr% = 5
                  IF FGScrnColr% = 14 THEN FGScrnColr% = 7
                  IF FGScrnColr% = 15 THEN FGScrnColr% = 7

                  BGScrnColr% = OneColr% \ 16
                  IF ShadowColr% = 7 THEN
                      COLOR FGScrnColr%, 0
                  ELSEIF ShadowColr% = 8 THEN
                      COLOR 8, 0
                  END IF
                  IF Shadow% = 1 THEN
                      PRINT MID$(ReadLine$(FindRow%), ScrnCol% - (ULCol% + 1));
                  ELSEIF Shadow% = 2 THEN
                      PRINT MID$(ReadLine$(FindRow%), ScrnCol% - (ULCol% - 3));
                  END IF
              NEXT
        NEXT
        ERASE ReadLine$: ERASE ReadColr%
    END IF
   
    IF EdgeYN% = 1 THEN
        Edge$ = " "
    END IF
   
    Title.Length% = LEN(Title$)
    COLOR BoxColrFG%, BoxColrBG%
    'ÚÄÄÄ¿   or  ÉÍÍÍ»
    LOCATE ULRow%, ULCol%, 0
    PRINT Edge$ + ULCorner$ + STRING$(LRCol% - ULCol%, HorLineTop$) + URCorner$ + Edge$;

    '³   ³   or  º   º
    LOCATE ULRow% + 1, ULCol%, 0
    PRINT Edge$ + VertLine$ + SPACE$(LRCol% - ULCol%) + VertLine$ + Edge$;

    IF Title$ <> "" THEN
        'ÃÄÄÄ´   or  ÇÄÄĶ         'made cross bar if there is a title
        LOCATE ULRow% + 2, ULCol%, 0
        PRINT Edge$ + LeftSide$ + STRING$(LRCol% - ULCol%, 196) + RightSide$ + Edge$;
    ELSEIF Title$ = "" THEN
        LOCATE ULRow% + 2, ULCol%, 0
        PRINT Edge$ + VertLine$ + SPACE$(LRCol% - ULCol%) + VertLine$ + Edge$;
    END IF

    '³   ³   or  º   º
    FOR Print.Box% = 1 TO (LRRow% - ULRow%) - 3
        LOCATE ULRow% + Print.Box% + 2, ULCol%, 0
        PRINT Edge$ + VertLine$ + SPACE$(LRCol% - ULCol%) + VertLine$ + Edge$;
    NEXT

    'ÀÄÄÄÙ  or  ÈÍÍͼ
    LOCATE LRRow%, ULCol%, 0
    PRINT Edge$ + LLCorner$ + STRING$(LRCol% - ULCol%, HorLineBot$) + LRCorner$ + Edge$;
    IF Title$ <> "" THEN
        LOCATE TitleRow%, TitleCol%, 0
        COLOR TitColrFG%, TitColrBG%
        PRINT Title$;
    END IF

END SUB